Reader Program of the Month

We’re waiting to discover you.

Send us a game program that you’ve written and maybe we’ll send you $100. Each month in First Screening, we’re going to print a program that one of our readers has written. If you think you have hidden talent as a game designer and you have a game that you think deserves recognition, send it to us. Be sure to let us know which computer it’s for and to include the complete computer printout. For more information on how to enter, see page 90.

This month’s. winner is Nick Thoele. Nick is a 17-year-old high school senior from Albuquerque, New Mexico. He’s been writing computer programs for four years and likes games best, though many of his programs don’t survive. “I just program the game, play it and destroy it,” he says. Nick’s game Destroyus is for the TRS-80 Model III.

DESTROYUS

Destroyus is a real-time action game for the TRS-80 Model III computer. It can be made slower by adding a simple loop to the program but it can’t be made any faster. Don’t worry, however. Although it only has one difficulty level, it is a tough game to master. Most of my friends who have tried it only got 50 points before they lost. You know how it is: You hit one Warg and you die.

How to Play

Back in medieval times, there existed a horrible creature known as the Destroyus, that created havoc and ruin everywhere it flew. In this game, you are the evil Destroyus, flying over cities destroying all who stand in your way. You must wipe out as many humans and injured Wargs as you can. Wargs are injured as a result of being attacked by your cohorts in evil, the Slayus. You don’t want to slay a Slayus. They’re your allies. And destroying a friend costs you 25 points. Running into an uninjured Warg costs you your life.

As Destroyus, you are represented on your screen by the letter “v.” Healthy Wargs are represented by the letter “W” while injured Wargs are seen as “I.” Humans have been given the letter “H” and the Slayus are depicted by the letter “S.”

Monsters

Including yourself and the humans, there are four types of monsters. The Wargs are good. They’re very muscular, 10 feet tall and resemble minotaurs with shaggy white hair. They’re smart, fierce, good fighters and equipped with magical swords with which they defend the humans and destroy Destroyus.

Friends of Destroyus, the Slayus are serpent-like creatures that measure about 12 evil feet in length. They coil like a cobra and attack humans.

As for the Destroyus itself, no one knows where it came from. It’s 50 feet long and totally black with a vulture-like head and huge dragon-like wings. Its six legs end in enormous talons and, what’s worse, it’s acid-breathing. It just has to get close to a human or an injured Warg and it’s curtains.

Movement

Your movement is restricted to horizontal. Pressing the “Z” key will make you fly left and pressing the “/” key will make you fly right. You move at a very fast speed and simply by flying over something, you can destroy it.

Strategy

The best strategy for this game is to avoid risky situations. This can best be accomplished by staying in open areas and only going for points when doing so is relatively safe. Watch out for what’s ahead. Wargs often form walls and flying into them means certain death. If you see a wall of Wargs heading for you early enough, it could save your life.

If Wargs destroy you a little sooner than you would like, there are a couple of things that can be done to help you last longer. First, you can slow down the program, but this subtracts from the fun of the game. A solution I recommend is to replace the “W” character (Warg) with a character that stands out more on the screen, such as a star. It is also suggested that the small “v” which is used on the Model III to represent Destroyus be replaced by a down arrow on the Model I. The down arrow is CHR$(92). Variations in the program such as awarding yourself a bonus Destroyus every 2500 points or so could also make the game more interesting.

Good luck and remember, as an injured Warg might say “Destroy us, Destroyus!”

10 'DESTROYUS          BY NICK THOELE
20 CLS:PRINT@320,"DESTROYUS";@448,"INSTRUCTIONS";:INPUTQ$
30 Z$=" '"+CHR$(92)+"'.":IFQ$="Y"ORQ$="YES"THENCLSELSE320
40 PRINT@69,"THE DESTROYUS IS AN EVIL, VULTURE-LIKE BIRD THAT"
50 PRINT"IS GREATLY FEARED BY HUMANS BECAUSE IT HAS BEEN KNOWN"
60 PRINT"TO DESTROY ENTIRE CITIES.  THE DESTROYUS FLIES OVER A"
70 PRINT"CITY AND BREATHS ACID AT THE PEOPLE THERE. HORRIBLE"
80 PRINT"AS DESTROYUS IS, BEINGS EXIST THAT CAN DESTROY IT."
90 PRINT"THESE BEINGS, KNOWN AS WARGS, CAN KILL THE DESTROYUS"
100 PRINT"BY USE OF THEIR SPECIAL MAGIC SWORDS.  THESE SWORDS"
110 PRINT"CAN SLAY ANYTHING THAT IS TRULY EVIL.  THE WARGS ARE"
120 PRINT"GOOD CREATURES THAT PROTECT THE HUMANS AT ALL TIMES."
130 PRINT"     THE SLAYUS ARE EVIL SERPENT PEOPLE THAT THINK"
140 PRINT"THE DESTROYUS IS A GOD.  THEY FOLLOW DESTROYUS TO"
150 PRINT"THE CITIES AND FIGHT THE WARGS THERE.  OCCASIONALLY"
160 PRINT"THEY INJURE A WARG, AND THIS ALLOWS THE DESTROYUS TO"
170 PRINT"KILL THE WARG.          <HIT ANY KEY TO CONTINUE>"
180 Q$=INKEY$:IFQ$=""THEN180ELSECLS
190 PRINT@197,"YOU ARE THE DESTROYUS, REPRESENTED BY THE";Z$
200 PRINT"YOU CAN MOVE LEFT BY PRESSING THE 'Z', OR RIGHT BY"
210 PRINT"PRESSING THE '/'.  WHEN THE DESTROYUS FLIES OVER"
220 PRINT"SOMETHING, HE BREATHS OUT A STREAM OF ACIS.  IF A"
230 PRINT"HUMAN, REPRESENTED BY 'H', IS DESTROYED, 10 POINTS"
240 PRINT"ARE SCORED.  IF AN INJURED WARG, REPRESENTED BY 'I',"
250 PRINT"IS DESTROYED, 50 POINTS ARE SCORED.  IF A SLAYUS,"
260 PRINT"REPRESENTED BY 'S', IS DESTROYED, -25 POINTS ARE"
270 PRINT"SCORED.  AN UNINJURED WARG, REPRESENTED BY 'W',"
280 PRINT"CANNOT BE DESTROYED.  IF YOU FLY OVER A WARG, THEN"
290 PRINT"THE WARG WILL DESTROY YOU AND THE GAME WILL BE OVER."
300 PRINTTAB(25);"<HIT ANY KEY TO START>"
310 Q$=IN KEY$:IFQ$=""THEN310ELSECLS
320 CLEAR99:RANDOM:E$=STRING$(64," "):D$="v":DIMC$(9),C(4)
330 C$(1)="W":C$(2)="W":C$(3)="W":C$(4)="W":C$(5)="S":C$(6)="S"
340 C$(7)="H":C$(8)="H":C$(9)="I":C(1)=87:C(2)=83:C(3)=72
350 C(4)=73:L=203:R-235:L$="Z":R$="/":H$="HIGH SCORE:"
355 TM=50
360 S$="SCORE:":P=219:' END OF INITIALIZATION
370 CLS:S=0:D=P
380 FORA=1TORND(4)+4:PRINT@906+RND(32),C$(RND(9));:NEXTA
390 PRINT@D," ";:Q$=INKEY$:IFQ$<>""THEN470
400 X=PEEK(D+15424):PRINT@128,E$;:PRINT@999," "
410 PRINT@13,S$;s;@35,H$;H;@D,D$;
420 IFX=C(2)THENS=S-25
440 IFX=C(3)THENS=S+10
450 IFX=C(4)THENS=S+50
460 GOTO380
470 IFQ$=L$THEND=D-1
480 IFQ$=R$THEND=D+1
490 IFD=LTHEND=L+1
500 IFD=RTHEND=R-1
510 GOTO400
520 FORA=1TO4:PRINT@D,CHR$(136);@d,CHR$(161);@d,CHR$(166);
530 PRINT@D,CHR$(182);@d,CHR$(147);@D,CHR$(134);:NEXTA:CLS
540 PRINT@320,S$;S:PRINT"A WARG GOT YOU!":IFS>HTHENH=S
550 PRINT@512,"ANOTHER GAME";:INPUTQ$:IFQ$="YES"THEN370
560 END